mirror of
https://github.com/dashpay/dash.git
synced 2024-12-27 04:52:59 +01:00
3233445aa7
747cd17404832604c50d03d58e11ba816bb229f7 build: no-longer fail default configure if BDB isn't available (fanquake)
Pull request description:
Inline with moving to descriptor (sqlite) wallets by default for 0.23,
this adapts the build system so that a default `./configure` invocation
no-longer fails if BDB isn't present. Currently, if configure is run
with no options, and no BDB is present, we'll fail with:
```bash
checking for Berkeley DB C++ headers... no
configure: error: libdb_cxx headers missing, Bitcoin Core requires this library for BDB wallet support (--without-bdb to disable BDB wallet support)
```
If descriptor wallets are to be the default, this behaviour no longer
makes sense, as a builder should be able to configure and build, to use
a wallet, without BDB installed, and without passing additional
arguments, i.e `--without-bdb` or `--with-incompatible-bdb`, to
configure.
With this change, running configure will no-longer fail, but will
instead print:
```bash
checking for Berkeley DB C++ headers... no
configure: WARNING: libdb_cxx headers missing
configure: WARNING: Bitcoin Core requires this library for BDB (legacy) wallet support
configure: WARNING: Passing --without-bdb will suppress this warning
checking for sqlite3 >= 3.7.17... yes
checking whether to build wallet with support for sqlite... yes
```
ACKs for top commit:
hebasto:
ACK 747cd17404832604c50d03d58e11ba816bb229f7, tested on Linux Mint 20.2 (x86_64) with the (un)installed system packages `libdb-dev` and `libdb++-dev`.
Tree-SHA512: ae316d71ad0803c9d4b02a5fedcade08242650d987cc047840493ba4a881e71ff48b099075bb7c325307d44744fcdeccb57f7fa8db4135c81a5835841f562afa
99 lines
3.4 KiB
Plaintext
99 lines
3.4 KiB
Plaintext
dnl Copyright (c) 2013-2015 The Bitcoin Core developers
|
|
dnl Distributed under the MIT software license, see the accompanying
|
|
dnl file COPYING or http://www.opensource.org/licenses/mit-license.php.
|
|
|
|
AC_DEFUN([BITCOIN_FIND_BDB48],[
|
|
AC_ARG_VAR(BDB_CFLAGS, [C compiler flags for BerkeleyDB, bypasses autodetection])
|
|
AC_ARG_VAR(BDB_LIBS, [Linker flags for BerkeleyDB, bypasses autodetection])
|
|
|
|
if test "x$use_bdb" = "xno"; then
|
|
use_bdb=no
|
|
elif test "x$BDB_CFLAGS" = "x"; then
|
|
AC_MSG_CHECKING([for Berkeley DB C++ headers])
|
|
BDB_CPPFLAGS=
|
|
bdbpath=X
|
|
bdb48path=X
|
|
bdbdirlist=
|
|
for _vn in 4.8 48 4 5 5.3 ''; do
|
|
for _pfx in b lib ''; do
|
|
bdbdirlist="$bdbdirlist ${_pfx}db${_vn}"
|
|
done
|
|
done
|
|
for searchpath in $bdbdirlist ''; do
|
|
test -n "${searchpath}" && searchpath="${searchpath}/"
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <${searchpath}db_cxx.h>
|
|
]],[[
|
|
#if !((DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR >= 8) || DB_VERSION_MAJOR > 4)
|
|
#error "failed to find bdb 4.8+"
|
|
#endif
|
|
]])],[
|
|
if test "x$bdbpath" = "xX"; then
|
|
bdbpath="${searchpath}"
|
|
fi
|
|
],[
|
|
continue
|
|
])
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <${searchpath}db_cxx.h>
|
|
]],[[
|
|
#if !(DB_VERSION_MAJOR == 4 && DB_VERSION_MINOR == 8)
|
|
#error "failed to find bdb 4.8"
|
|
#endif
|
|
]])],[
|
|
bdb48path="${searchpath}"
|
|
break
|
|
],[])
|
|
done
|
|
if test "x$bdbpath" = "xX"; then
|
|
use_bdb=no
|
|
AC_MSG_RESULT([no])
|
|
AC_MSG_WARN([libdb_cxx headers missing])
|
|
AC_MSG_WARN(AC_PACKAGE_NAME[ requires this library for BDB (legacy) wallet support])
|
|
AC_MSG_WARN([Passing --without-bdb will suppress this warning])
|
|
elif test "x$bdb48path" = "xX"; then
|
|
BITCOIN_SUBDIR_TO_INCLUDE(BDB_CPPFLAGS,[${bdbpath}],db_cxx)
|
|
AC_ARG_WITH([incompatible-bdb],[AS_HELP_STRING([--with-incompatible-bdb], [allow using a bdb version other than 4.8])],[
|
|
AC_MSG_WARN([Found Berkeley DB other than 4.8])
|
|
AC_MSG_WARN([BDB (legacy) wallets opened by this build will not be portable!])
|
|
use_bdb=yes
|
|
],[
|
|
AC_MSG_WARN([Found Berkeley DB other than 4.8])
|
|
AC_MSG_WARN([BDB (legacy) wallets opened by this build would not be portable!])
|
|
AC_MSG_WARN([If this is intended, pass --with-incompatible-bdb])
|
|
AC_MSG_WARN([Passing --without-bdb will suppress this warning])
|
|
use_bdb=no
|
|
])
|
|
else
|
|
BITCOIN_SUBDIR_TO_INCLUDE(BDB_CPPFLAGS,[${bdb48path}],db_cxx)
|
|
bdbpath="${bdb48path}"
|
|
use_bdb=yes
|
|
fi
|
|
else
|
|
BDB_CPPFLAGS=${BDB_CFLAGS}
|
|
fi
|
|
AC_SUBST(BDB_CPPFLAGS)
|
|
|
|
if test "x$use_bdb" = "xno"; then
|
|
use_bdb=no
|
|
elif test "x$BDB_LIBS" = "x"; then
|
|
# TODO: Ideally this could find the library version and make sure it matches the headers being used
|
|
for searchlib in db_cxx-4.8 db_cxx db4_cxx; do
|
|
AC_CHECK_LIB([$searchlib],[main],[
|
|
BDB_LIBS="-l${searchlib}"
|
|
break
|
|
])
|
|
done
|
|
if test "x$BDB_LIBS" = "x"; then
|
|
AC_MSG_WARN([libdb_cxx headers missing])
|
|
AC_MSG_WARN(AC_PACKAGE_NAME[ requires this library for BDB (legacy) wallet support])
|
|
AC_MSG_WARN([Passing --without-bdb will suppress this warning])
|
|
fi
|
|
fi
|
|
if test "x$use_bdb" != "xno"; then
|
|
AC_SUBST(BDB_LIBS)
|
|
AC_DEFINE([USE_BDB], [1], [Define if BDB support should be compiled in])
|
|
use_bdb=yes
|
|
fi
|
|
])
|