mirror of
https://github.com/dashpay/dash.git
synced 2024-12-26 12:32:48 +01:00
d3a9042e01
bb99c4e684bbd3053ecf7a789049b11b29260189 build: update boost macros to latest upstream (fanquake) Pull request description: Fixes: #16803 I opened an [upstream PR](https://github.com/autoconf-archive/autoconf-archive/pull/197) to improve the Boost error reporting, so pull the latest macros. ACKs for top commit: laanwj: Code review ACK bb99c4e684bbd3053ecf7a789049b11b29260189 jonatack: Sanity check ACK bb99c4e684bbd3053ecf7a789049b11b29260189, light code read, built and ran tests on Debian 4.19.37-5+deb10u2 (2019-08-08) x86_64 GNU/Linux. Only tested the happy path. Tree-SHA512: 34704ed623ac0085215fd874a23fde8f6e39a69fa20d78472b0c4d2306dc101c0571fa26c4c8821600746b94daaaf05faf6d15546899d588081c26357d29ec46
122 lines
4.1 KiB
Plaintext
122 lines
4.1 KiB
Plaintext
# ===========================================================================
|
|
# https://www.gnu.org/software/autoconf-archive/ax_boost_system.html
|
|
# ===========================================================================
|
|
#
|
|
# SYNOPSIS
|
|
#
|
|
# AX_BOOST_SYSTEM
|
|
#
|
|
# DESCRIPTION
|
|
#
|
|
# Test for System library from the Boost C++ libraries. The macro requires
|
|
# a preceding call to AX_BOOST_BASE. Further documentation is available at
|
|
# <http://randspringer.de/boost/index.html>.
|
|
#
|
|
# This macro calls:
|
|
#
|
|
# AC_SUBST(BOOST_SYSTEM_LIB)
|
|
#
|
|
# And sets:
|
|
#
|
|
# HAVE_BOOST_SYSTEM
|
|
#
|
|
# LICENSE
|
|
#
|
|
# Copyright (c) 2008 Thomas Porschberg <thomas@randspringer.de>
|
|
# Copyright (c) 2008 Michael Tindal
|
|
# Copyright (c) 2008 Daniel Casimiro <dan.casimiro@gmail.com>
|
|
#
|
|
# Copying and distribution of this file, with or without modification, are
|
|
# permitted in any medium without royalty provided the copyright notice
|
|
# and this notice are preserved. This file is offered as-is, without any
|
|
# warranty.
|
|
|
|
#serial 20
|
|
|
|
AC_DEFUN([AX_BOOST_SYSTEM],
|
|
[
|
|
AC_ARG_WITH([boost-system],
|
|
AS_HELP_STRING([--with-boost-system@<:@=special-lib@:>@],
|
|
[use the System library from boost - it is possible to specify a certain library for the linker
|
|
e.g. --with-boost-system=boost_system-gcc-mt ]),
|
|
[
|
|
if test "$withval" = "no"; then
|
|
want_boost="no"
|
|
elif test "$withval" = "yes"; then
|
|
want_boost="yes"
|
|
ax_boost_user_system_lib=""
|
|
else
|
|
want_boost="yes"
|
|
ax_boost_user_system_lib="$withval"
|
|
fi
|
|
],
|
|
[want_boost="yes"]
|
|
)
|
|
|
|
if test "x$want_boost" = "xyes"; then
|
|
AC_REQUIRE([AC_PROG_CC])
|
|
AC_REQUIRE([AC_CANONICAL_BUILD])
|
|
CPPFLAGS_SAVED="$CPPFLAGS"
|
|
CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
|
|
export CPPFLAGS
|
|
|
|
LDFLAGS_SAVED="$LDFLAGS"
|
|
LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
|
|
export LDFLAGS
|
|
|
|
AC_CACHE_CHECK(whether the Boost::System library is available,
|
|
ax_cv_boost_system,
|
|
[AC_LANG_PUSH([C++])
|
|
CXXFLAGS_SAVE=$CXXFLAGS
|
|
CXXFLAGS=
|
|
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <boost/system/error_code.hpp>]],
|
|
[[boost::system::error_category *a = 0;]])],
|
|
ax_cv_boost_system=yes, ax_cv_boost_system=no)
|
|
CXXFLAGS=$CXXFLAGS_SAVE
|
|
AC_LANG_POP([C++])
|
|
])
|
|
if test "x$ax_cv_boost_system" = "xyes"; then
|
|
AC_SUBST(BOOST_CPPFLAGS)
|
|
|
|
AC_DEFINE(HAVE_BOOST_SYSTEM,,[define if the Boost::System library is available])
|
|
BOOSTLIBDIR=`echo $BOOST_LDFLAGS | sed -e 's/@<:@^\/@:>@*//'`
|
|
|
|
LDFLAGS_SAVE=$LDFLAGS
|
|
if test "x$ax_boost_user_system_lib" = "x"; then
|
|
for libextension in `ls -r $BOOSTLIBDIR/libboost_system* 2>/dev/null | sed 's,.*/lib,,' | sed 's,\..*,,'` ; do
|
|
ax_lib=${libextension}
|
|
AC_CHECK_LIB($ax_lib, exit,
|
|
[BOOST_SYSTEM_LIB="-l$ax_lib"; AC_SUBST(BOOST_SYSTEM_LIB) link_system="yes"; break],
|
|
[link_system="no"])
|
|
done
|
|
if test "x$link_system" != "xyes"; then
|
|
for libextension in `ls -r $BOOSTLIBDIR/boost_system* 2>/dev/null | sed 's,.*/,,' | sed -e 's,\..*,,'` ; do
|
|
ax_lib=${libextension}
|
|
AC_CHECK_LIB($ax_lib, exit,
|
|
[BOOST_SYSTEM_LIB="-l$ax_lib"; AC_SUBST(BOOST_SYSTEM_LIB) link_system="yes"; break],
|
|
[link_system="no"])
|
|
done
|
|
fi
|
|
|
|
else
|
|
for ax_lib in $ax_boost_user_system_lib boost_system-$ax_boost_user_system_lib; do
|
|
AC_CHECK_LIB($ax_lib, exit,
|
|
[BOOST_SYSTEM_LIB="-l$ax_lib"; AC_SUBST(BOOST_SYSTEM_LIB) link_system="yes"; break],
|
|
[link_system="no"])
|
|
done
|
|
|
|
fi
|
|
if test "x$ax_lib" = "x"; then
|
|
AC_MSG_ERROR(Could not find a version of the Boost::System library!)
|
|
fi
|
|
if test "x$link_system" = "xno"; then
|
|
AC_MSG_ERROR(Could not link against $ax_lib !)
|
|
fi
|
|
fi
|
|
|
|
CPPFLAGS="$CPPFLAGS_SAVED"
|
|
LDFLAGS="$LDFLAGS_SAVED"
|
|
fi
|
|
])
|