mirror of
https://github.com/dashpay/dash.git
synced 2024-12-28 21:42:47 +01:00
7b49f22bdb
8225239 Merge #433: Make the libcrypto detection fail the newer API. 12de863 Make the libcrypto detection fail the newer API. 2928420 Merge #427: Remove Schnorr from travis as well 8eecc4a Remove Schnorr from travis as well a8abae7 Merge #310: Add exhaustive test for group functions on a low-order subgroup b4ceedf Add exhaustive test for verification 83836a9 Add exhaustive tests for group arithmetic, signing, and ecmult on a small group 20b8877 Add exhaustive test for group functions on a low-order subgroup 80773a6 Merge #425: Remove Schnorr experiment e06e878 Remove Schnorr experiment 04c8ef3 Merge #407: Modify parameter order of internal functions to match API parameter order 6e06696 Merge #411: Remove guarantees about memcmp-ability 40c8d7e Merge #421: Update scalar_4x64_impl.h a922365 Merge #422: Restructure nonce clearing 3769783 Restructure nonce clearing 0f9e69d Restructure nonce clearing 9d67afa Update scalar_4x64_impl.h 7d15cd7 Merge #413: fix auto-enabled static precompuatation 00c5d2e fix auto-enabled static precompuatation 91219a1 Remove guarantees about memcmp-ability 353c1bf Fix secp256k1_ge_set_table_gej_var parameter order 541b783 Fix secp256k1_ge_set_all_gej_var parameter order 7d893f4 Fix secp256k1_fe_inv_all_var parameter order git-subtree-dir: src/secp256k1 git-subtree-split: 8225239f490f79842a5a3b82ad6cc8aa11d5208e
70 lines
2.3 KiB
Plaintext
70 lines
2.3 KiB
Plaintext
dnl libsecp25k1 helper checks
|
|
AC_DEFUN([SECP_INT128_CHECK],[
|
|
has_int128=$ac_cv_type___int128
|
|
])
|
|
|
|
dnl escape "$0x" below using the m4 quadrigaph @S|@, and escape it again with a \ for the shell.
|
|
AC_DEFUN([SECP_64BIT_ASM_CHECK],[
|
|
AC_MSG_CHECKING(for x86_64 assembly availability)
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <stdint.h>]],[[
|
|
uint64_t a = 11, tmp;
|
|
__asm__ __volatile__("movq \@S|@0x100000000,%1; mulq %%rsi" : "+a"(a) : "S"(tmp) : "cc", "%rdx");
|
|
]])],[has_64bit_asm=yes],[has_64bit_asm=no])
|
|
AC_MSG_RESULT([$has_64bit_asm])
|
|
])
|
|
|
|
dnl
|
|
AC_DEFUN([SECP_OPENSSL_CHECK],[
|
|
has_libcrypto=no
|
|
m4_ifdef([PKG_CHECK_MODULES],[
|
|
PKG_CHECK_MODULES([CRYPTO], [libcrypto], [has_libcrypto=yes],[has_libcrypto=no])
|
|
if test x"$has_libcrypto" = x"yes"; then
|
|
TEMP_LIBS="$LIBS"
|
|
LIBS="$LIBS $CRYPTO_LIBS"
|
|
AC_CHECK_LIB(crypto, main,[AC_DEFINE(HAVE_LIBCRYPTO,1,[Define this symbol if libcrypto is installed])],[has_libcrypto=no])
|
|
LIBS="$TEMP_LIBS"
|
|
fi
|
|
])
|
|
if test x$has_libcrypto = xno; then
|
|
AC_CHECK_HEADER(openssl/crypto.h,[
|
|
AC_CHECK_LIB(crypto, main,[
|
|
has_libcrypto=yes
|
|
CRYPTO_LIBS=-lcrypto
|
|
AC_DEFINE(HAVE_LIBCRYPTO,1,[Define this symbol if libcrypto is installed])
|
|
])
|
|
])
|
|
LIBS=
|
|
fi
|
|
if test x"$has_libcrypto" = x"yes" && test x"$has_openssl_ec" = x; then
|
|
AC_MSG_CHECKING(for EC functions in libcrypto)
|
|
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
|
|
#include <openssl/ec.h>
|
|
#include <openssl/ecdsa.h>
|
|
#include <openssl/obj_mac.h>]],[[
|
|
EC_KEY *eckey = EC_KEY_new_by_curve_name(NID_secp256k1);
|
|
ECDSA_sign(0, NULL, 0, NULL, NULL, eckey);
|
|
ECDSA_verify(0, NULL, 0, NULL, 0, eckey);
|
|
EC_KEY_free(eckey);
|
|
ECDSA_SIG *sig_openssl;
|
|
sig_openssl = ECDSA_SIG_new();
|
|
(void)sig_openssl->r;
|
|
ECDSA_SIG_free(sig_openssl);
|
|
]])],[has_openssl_ec=yes],[has_openssl_ec=no])
|
|
AC_MSG_RESULT([$has_openssl_ec])
|
|
fi
|
|
])
|
|
|
|
dnl
|
|
AC_DEFUN([SECP_GMP_CHECK],[
|
|
if test x"$has_gmp" != x"yes"; then
|
|
CPPFLAGS_TEMP="$CPPFLAGS"
|
|
CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
|
|
LIBS_TEMP="$LIBS"
|
|
LIBS="$GMP_LIBS $LIBS"
|
|
AC_CHECK_HEADER(gmp.h,[AC_CHECK_LIB(gmp, __gmpz_init,[has_gmp=yes; GMP_LIBS="$GMP_LIBS -lgmp"; AC_DEFINE(HAVE_LIBGMP,1,[Define this symbol if libgmp is installed])])])
|
|
CPPFLAGS="$CPPFLAGS_TEMP"
|
|
LIBS="$LIBS_TEMP"
|
|
fi
|
|
])
|